From 1f79f8c76c408ac98891261981815566c12eabe3 Mon Sep 17 00:00:00 2001
From: Brian McKenna <brian@brianmckenna.org>
Date: Thu, 23 Nov 2023 15:23:58 +1100
Subject: [PATCH] sgdboop: init at 1.2.8

Move to by-name and update license

Format
---
 pkgs/by-name/sg/sgdboop/package.nix | 50 +++++++++++++++++++++++++++++
 1 file changed, 50 insertions(+)
 create mode 100644 pkgs/by-name/sg/sgdboop/package.nix

diff --git a/pkgs/by-name/sg/sgdboop/package.nix b/pkgs/by-name/sg/sgdboop/package.nix
new file mode 100644
index 000000000000000..cff430340b25abb
--- /dev/null
+++ b/pkgs/by-name/sg/sgdboop/package.nix
@@ -0,0 +1,50 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  curl,
+  iup,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "sgdboop";
+  version = "1.2.8";
+
+  src = fetchFromGitHub {
+    owner = "SteamGridDB";
+    repo = "SGDBoop";
+    rev = "v${version}";
+    hash = "sha256-bdSzTwObMEBe1pHTDwXeJ3GXmOwwFp4my7qTmifX218=";
+  };
+
+  makeFlags = [
+    # Makefile copies a bundled libiup.so, so put it somewhere it won't be found
+    "USER_LIB_PATH=ignored"
+
+    # The Flakepak install just copies things to /app - otherwise wants to do things with XDG
+    "FLATPAK_ID=fake"
+  ];
+
+  postPatch = ''
+    sed -i "s|Exec=|Exec=$out/bin/|" linux-release/com.steamgriddb.SGDBoop.desktop
+    sed -i "s|/app/|$out/|g" Makefile
+  '';
+
+  postInstall = ''
+    rm -r "$out/share/metainfo"
+  '';
+
+  buildInputs = [
+    curl
+    iup
+  ];
+
+  meta = {
+    description = "A program used for applying custom artwork to Steam, using SteamGridDB";
+    homepage = "https://github.com/SteamGridDB/SGDBoop/";
+    license = lib.licenses.zlib;
+    maintainers = [ lib.maintainers.saturn745 ];
+    mainProgram = "SGDBoop";
+    platforms = lib.platforms.linux;
+  };
+}