generating .pb.h files with cmake?

[ctriley]

TAG: stable
Language: C++

SICP

ARM Mac 12.3 (21E230)?

What did you do?
I'm trying to use cmake's FetchContent to include or-tools in a C++ library. My project structure is as follows:

├── CMakeLists.txt
├── src
│   ├── CMakeLists.txt # creates the dynamic library
│   ├── [various .cc/.h files]
│   ├── staticlib1
│   │   ├── CMakeLists.txt # creates a static library
│   │   └── [various .cc/.h files]
│   └── staticlib2
│       ├── CMakeLists.txt # creates another static library
│       └── [various .cc/.h files]
└── main.cc

In the top level CMakeLists.txt I have:

    set(FETCHCONTENT_QUIET OFF)
    include(FetchContent)
    FetchContent_Declare(
            ortools
            GIT_REPOSITORY https://github.com/google/or-tools.git
            GIT_TAG        stable
    )
    set(BUILD_SHARED_LIBS ON)
    set(BUILD_DEPS ON)
    set(BUILD_SAMPLES OFF)
    set(BUILD_EXAMPLES OFF)
    FetchContent_MakeAvailable(ortools)
    add_definitions(-DORTOOLS)

Because of this structure, I need to include the or-tools header files in the static libraries, and then link the or-tools library against the dynamic library. Trying to link or-tools against both the static and dynamic libraries produces the following error:

ERROR: Something is wrong with flag 'flagfile' in file 'Users/username/project-root/cmake-build-debug/ortools-download/ortools_project-prefix/src/ortools_project-build/_deps/absl-src/absl/flags/parse.cc'. One possibility: file 'Users/username/project-root/cmake-build-debug/ortools-download/ortools_project-prefix/src/ortools_project-build/_deps/absl-src/absl/flags/parse.cc' is being linked both statically and dynamically into this executable. e.g. some files listed as srcs to a test and also listed as srcs of some shared lib deps of the same test.

Therefore, in the src/staticlib1/CMakeLists.txt I added all the header files for the dependencies:

include_directories(${ortools_SOURCE_DIR})
include_directories(${absl_SOURCE_DIR})
...

and instead of linking each static library to ortools::ortools I just link it at the top level dynamic library:

add_library(${dynamiclib} SHARED ${SOURCE_FILES_SRC})
target_link_libraries(${dynamiclib} ${staticlib1} ${staticlib2} ortools::ortools)

This seems to be working so far, but I get stuck because I don't know how to generate the .pb.h files (e.x. ortools/linear_solver/linear_solver.pb.h) and end up with an error generating the static libraries:

/Users/username/project/cmake-build-debug/_deps/ortools-src/ortools/linear_solver/linear_solver.h:159:10: fatal error: 'ortools/linear_solver/linear_solver.pb.h' file not found

Is there a way to generate these files with cmake so that I can use include_directories to include them in as headers in the static libraries?

[Mizux]

These file are generated by CMake using protoc

or-tools/cmake/cpp.cmake

Lines 146 to 199 in 49b6301

	# Generate Protobuf cpp sources
	set(PROTO_HDRS)
	set(PROTO_SRCS)
	file(GLOB_RECURSE proto_files RELATIVE ${PROJECT_SOURCE_DIR}
	"ortools/bop/*.proto"
	"ortools/constraint_solver/*.proto"
	"ortools/glop/*.proto"
	"ortools/graph/*.proto"
	"ortools/linear_solver/*.proto"
	"ortools/linear_solver/*.proto"
	"ortools/packing/*.proto"
	"ortools/sat/*.proto"
	"ortools/scheduling/*.proto"
	"ortools/util/*.proto"
	)
	if(USE_PDLP)
	file(GLOB_RECURSE pdlp_proto_files RELATIVE ${PROJECT_SOURCE_DIR} "ortools/pdlp/*.proto")
	list(APPEND proto_files ${pdlp_proto_files})
	endif()
	if(USE_SCIP)
	file(GLOB_RECURSE gscip_proto_files RELATIVE ${PROJECT_SOURCE_DIR} "ortools/gscip/*.proto")
	list(APPEND proto_files ${gscip_proto_files})
	endif()
	## Get Protobuf include dir
	get_target_property(protobuf_dirs protobuf::libprotobuf INTERFACE_INCLUDE_DIRECTORIES)
	foreach(dir IN LISTS protobuf_dirs)
	if (NOT "${dir}" MATCHES "INSTALL_INTERFACE|-NOTFOUND")
	message(STATUS "Adding proto path: ${dir}")
	list(APPEND PROTO_DIRS "--proto_path=${dir}")
	endif()
	endforeach()
	foreach(PROTO_FILE IN LISTS proto_files)
	#message(STATUS "protoc proto(cc): ${PROTO_FILE}")
	get_filename_component(PROTO_DIR ${PROTO_FILE} DIRECTORY)
	get_filename_component(PROTO_NAME ${PROTO_FILE} NAME_WE)
	set(PROTO_HDR ${PROJECT_BINARY_DIR}/${PROTO_DIR}/${PROTO_NAME}.pb.h)
	set(PROTO_SRC ${PROJECT_BINARY_DIR}/${PROTO_DIR}/${PROTO_NAME}.pb.cc)
	#message(STATUS "protoc hdr: ${PROTO_HDR}")
	#message(STATUS "protoc src: ${PROTO_SRC}")
	add_custom_command(
	OUTPUT ${PROTO_SRC} ${PROTO_HDR}
	COMMAND ${PROTOC_PRG}
	"--proto_path=${PROJECT_SOURCE_DIR}"
	${PROTO_DIRS}
	"--cpp_out=${PROJECT_BINARY_DIR}"
	${PROTO_FILE}
	DEPENDS ${PROTO_FILE} ${PROTOC_PRG}
	COMMENT "Generate C++ protocol buffer for ${PROTO_FILE}"
	VERBATIM)
	list(APPEND PROTO_HDRS ${PROTO_HDR})
	list(APPEND PROTO_SRCS ${PROTO_SRC})
	endforeach()

and they should be located in

or-tools/cmake/cpp.cmake

Line 183 in 49b6301

set(PROTO_HDR ${PROJECT_BINARY_DIR}/${PROTO_DIR}/${PROTO_NAME}.pb.h)

so I suspect an issue in the target_include_directories() of ortools::ortools target

dev Note:
ortools::ortools include directories

or-tools/cmake/cpp.cmake

Lines 92 to 94 in 49b6301

	target_include_directories(${PROJECT_NAME} INTERFACE
	$<BUILD_INTERFACE:${PROJECT_SOURCE_DIR}>
	$<BUILD_INTERFACE:${PROJECT_BINARY_DIR}>

link between ortools_proto and ortools targets.

or-tools/cmake/cpp.cmake

Lines 216 to 220 in 49b6301

	add_library(${PROJECT_NAMESPACE}::proto ALIAS ${PROJECT_NAME}_proto)
	# Add ${PROJECT_NAMESPACE}::proto to libortools
	#target_link_libraries(${PROJECT_NAME} PRIVATE ${PROJECT_NAMESPACE}::proto)
	target_sources(${PROJECT_NAME} PRIVATE $<TARGET_OBJECTS:${PROJECT_NAMESPACE}::proto>)
	add_dependencies(${PROJECT_NAME} ${PROJECT_NAMESPACE}::proto)

[Mizux]

upon reflexion, I think the issue is the ortools_proto aka ortools::proto is not build before you staticlib1 thus header are still not available.

you may try to add add_dependencies(${staticlib1} ortools::proto) to force the build of ortools::proto before staticlib1 aka execute the generation of the pb.h earlier.

half off topic: I have difficulty to exactly understand why target_link_libraries(${staticlib1} PRIVATE ortools::ortools) would be a problem.
which CMake generator are you using on your Mac ? (note if you don't set one explicitly you can use cmake -G to display the default (*) one)

[ctriley]

Yeah I'm not really sure what I'm doing incorrectly.

I changed my code so that I'm only calling target_link_libraries(lib PRIVATE ortools::ortools) once. In order to do that I had to include the header files

    set(FETCHCONTENT_QUIET OFF)
    include(FetchContent)
    FetchContent_Declare(
            ortools
            GIT_REPOSITORY https://github.com/google/or-tools.git
            GIT_TAG        stable
    )
    set(BUILD_SHARED_LIBS ON)
    set(BUILD_DEPS ON)
    set(BUILD_SAMPLES OFF)
    set(BUILD_EXAMPLES OFF)
    FetchContent_MakeAvailable(ortools)
    add_definitions(-DORTOOLS)
    include_directories(${ortools_SOURCE_DIR})
    include_directories(${ortools_BINARY_DIR})
    include_directories(${absl_SOURCE_DIR})
    include_directories(${protobuf_SOURCE_DIR}/../src)

Then I'm building a bunch of static libraries, none of which are linked to ortools, but some of which include headers from ortools.

Then I link all those static libraries together into a shared library and to ortools:

target_link_libraries(${shared_library} PRIVATE ${all_the_static_libraries} ortools::ortools)

Everything compiles, but when I go to run the program immediately crashes with the error:

ERROR: Something is wrong with flag 'flagfile' in file 'Users/connorriley/dial-a-ride-dispatcher/cmake-build-debug/_deps/absl-src/absl/flags/parse.cc'. One possibility: file 'Users/connorriley/dial-a-ride-dispatcher/cmake-build-debug/_deps/absl-src/absl/flags/parse.cc' is being linked both statically and dynamically into this executable. e.g. some files listed as srcs to a test and also listed as srcs of some shared lib deps of the same test.

The executable I'm running is linked as such:

add_executable(dispatcher main.cc)
target_link_libraries(dispatcher PRIVATE ${shared_library} ${Boost_LIBRARIES} OpenMP::OpenMP_CXX)

I'm really out of my skill set in terms of what I should be doing to try to debug this. Any suggestions you have would be appreciated.

[ctriley]

Update, I got my code compiling, I still don't really understand what was going wrong. The only thing I changed from above is instead of having

    set(BUILD_SHARED_LIBS ON)

I set it to

    set(BUILD_SHARED_LIBS OFF)

The thing that clued me in to this might being the issue was the discussion here: abseil/abseil-cpp#125
which one of the maintainers of absl says:

"Unfortunately, Abseil has not been designed with use in dynamic libraries in mind (https://abseil.io/about/compatibility) and I don't know of a way to fix this issue in a way that's portable across all of the platforms that Abseil supports."

I'm not sure if that discussion is relevant, but if anyone else comes across this I figured I'd leave it here.

[rlorigro]

Hi, I was following along with your solution and noticed this:

    include_directories(${protobuf_SOURCE_DIR}/../src)

This will result in an incorrect path, because the .. should not be involved. The /src/ dir is a direct child of the protobuf_SOURCE_DIR. I was using the above answer and as a result my build was trying to find the protobuf header from my system location, causing a version mismatch, and compiler errors. I uninstalled my system level libprotobuf-dev because it was not needed by anything else, and removed the .., which fixed the issue. So the corrected solution looks like this:

include_directories(
        ${ortools_SOURCE_DIR}
        ${ortools_BINARY_DIR}
        ${absl_SOURCE_DIR}
        ${protobuf_SOURCE_DIR}/src
)

Just wanted to add this in case anyone else gets caught up by the same thing.