forked from jose1711/jpegpixi
-
Notifications
You must be signed in to change notification settings - Fork 0
/
acinclude.m4
166 lines (158 loc) · 5.82 KB
/
acinclude.m4
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
## This file is part of jpegpixi, a program to interpolate pixels in
## JFIF image files.
## Copyright (C) 2001, 2002, 2003, 2004, 2005 Martin Dickopp
##
## This file is free software; the copyright holder gives unlimited
## permission to copy and/or distribute it, with or without
## modifications, as long as this notice is preserved.
##
## This program is distributed in the hope that it will be useful,
## but WITHOUT ANY WARRANTY, to the extent permitted by law; without
## even the implied warranty of MERCHANTABILITY or FITNESS FOR A
## PARTICULAR PURPOSE.
# MD_PATH_PROG(PROGRAM)
# ---------------------
# Set PROGRAM to the path to PROGRAM, or to `missing' if the program is not
# available.
AC_DEFUN([MD_PATH_PROG],
[AS_VAR_PUSHDEF([md_Program], [md_path_$1])dnl
AS_VAR_SET(md_Program, [])
AC_ARG_WITH([$1],
AC_HELP_STRING([--with-$1=PROGRAM], [use PROGRAM as $1 executable]),
[case $withval in
yes)
;;
no)
AS_VAR_SET(md_Program, missing)
;;
*)
AS_VAR_SET(md_Program, ["$withval"])
;;
esac])
AS_IF([test "x[]AS_VAR_GET(md_Program)" != x],
[AS_TR_CPP([$1])="AS_VAR_GET(md_Program)"],
[AC_PATH_PROG(AS_TR_CPP([$1]), [$1], missing)])dnl
AS_VAR_POPDEF([md_Program])dnl
])# MD_PATH_PROG
# MD_PATH(PACKAGE, HEADER, LIBRARY, SYMBOL)
# -----------------------------------------
# Set PACKAGE_CPPFLAGS and PACKAGE_LIBS to the flags needed to compile/link with PACKAGE. HEADER and LIBRARY
# should be a header file and a library, respectively, belonging to PACKAGE. SYMBOL should be a SYMBOL in
# LIBRARY. If the package is available, define HAVE_PACKAGE.
AC_DEFUN([MD_PATH],
[AS_VAR_PUSHDEF([md_Package], [md_path_have_$1])dnl
AS_VAR_PUSHDEF([md_Inc], [md_path_include_$1])dnl
AS_VAR_PUSHDEF([md_Lib], [md_path_lib_$1])dnl
AS_VAR_SET(md_Package, yes)
AS_VAR_SET(md_Inc, [])
AS_VAR_SET(md_Lib, [])
AC_ARG_WITH([$1],
AC_HELP_STRING([--with-$1=DIR], [search $1 header files in DIR/include, library in DIR/lib]),
[case $withval in
yes)
AS_VAR_SET(md_Package, yes)
;;
no)
AS_VAR_SET(md_Package, no)
;;
*)
AS_VAR_SET(md_Package, yes)
AS_VAR_SET(md_Inc, ["$withval/include"])
AS_VAR_SET(md_Lib, ["$withval/lib"])
;;
esac])
AC_ARG_WITH([$1-include],
AC_HELP_STRING([--with-$1-include=DIR], [search $1 header files in DIR]),
[case $withval in
yes)
AS_VAR_SET(md_Package, yes)
;;
no)
AS_VAR_SET(md_Package, no)
;;
*)
AS_VAR_SET(md_Package, yes)
AS_VAR_SET(md_Inc, ["$withval"])
;;
esac])
AC_ARG_WITH([$1-lib],
AC_HELP_STRING([--with-$1-lib=DIR], [search $1 library in DIR]),
[case $withval in
yes)
AS_VAR_SET(md_Package, yes)
;;
no)
AS_VAR_SET(md_Package, no)
;;
*)
AS_VAR_SET(md_Package, yes)
AS_VAR_SET(md_Lib, ["$withval"])
;;
esac])
AS_TR_CPP([$1]_CPPFLAGS)= AS_TR_CPP([$1]_LIBS)=
AS_IF([test AS_VAR_GET(md_Package) = yes],
[AS_IF([test "x[]AS_VAR_GET(md_Inc)" != x], [AS_TR_CPP([$1]_CPPFLAGS)="-I[]AS_VAR_GET(md_Inc)"])
AS_IF([test "x[]AS_VAR_GET(md_Lib)" != x], [AS_TR_CPP([$1]_LIBS)="-L[]AS_VAR_GET(md_Lib)"])
save_CPPFLAGS="$CPPFLAGS"; CPPFLAGS="$CPPFLAGS $[]AS_TR_CPP([$1]_CPPFLAGS)"
AC_CHECK_HEADER([$2],
[save_LDFLAGS="$LDFLAGS"; LDFLAGS="$LDFLAGS $[]AS_TR_CPP([$1]_LIBS)"
AC_CHECK_LIB([$3], [$4], [AS_TR_CPP([$1]_LIBS)="$[]AS_TR_CPP([$1]_LIBS) -l[$3]"], [AS_VAR_SET(md_Package, no)])
LDFLAGS="$save_LDFLAGS"], [AS_VAR_SET(md_Package, no)], [AC_INCLUDES_DEFAULT])
CPPFLAGS="$save_CPPFLAGS"])
AH_TEMPLATE(AS_TR_CPP(HAVE_[$1]), [Define if package `$1' is available.])dnl
AS_IF([test AS_VAR_GET(md_Package) = yes], [AC_DEFINE(AS_TR_CPP(HAVE_[$1]), [1])])dnl
AS_VAR_POPDEF([md_Lib])dnl
AS_VAR_POPDEF([md_Inc])dnl
AS_VAR_POPDEF([md_Package])dnl
])# MD_PATH
# MD_CHECK_TYPE_SYS_ERRLIST
# -------------------------
# Set SYS_ERRLIST_TYPE to the type of sys_errlist [0].
AC_DEFUN([MD_CHECK_TYPE_SYS_ERRLIST],
[AC_CACHE_CHECK([for type of sys_errlist elements], [md_cv_var_type_sys_errlist],
[md_cv_var_type_sys_errlist='char *'
for md_type_sys_errlist in 'const char *const' 'const char *' 'char *const'; do
AC_COMPILE_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
[extern $md_type_sys_errlist sys_errlist @<:@@:>@;])],
[md_cv_var_type_sys_errlist="$md_type_sys_errlist"; break])
done])
AC_DEFINE_UNQUOTED(SYS_ERRLIST_TYPE, [$md_cv_var_type_sys_errlist], [Define to the type of `sys_errlist' elements.])dnl
])# MD_CHECK_TYPE_SYS_ERRLIST
# MD_NLS
# ------
# Test for Native Language Support. If supported, HAVE_NLS is defined and SUBDIR_PO is substituted with `po'.
# Otherwise, SUBDIR_PO is substituted with an empty string. XGETTEXT, MSGMERGE, and MSGFMT are replaced by
# the paths of the respective programs.
#
AC_DEFUN([MD_NLS],
[AC_ARG_ENABLE([nls], AC_HELP_STRING([--disable-nls], [do not use Native Language Support]),
[md_nls="$enableval"], [md_nls=yes])
AM_MISSING_PROG([XGETTEXT], [xgettext])
AM_MISSING_PROG([MSGMERGE], [msgmerge])
AM_MISSING_PROG([MSGFMT], [msgfmt])
if test "x$md_nls" != xyes && test "x$md_nls" != xno; then
AC_MSG_WARN([unrecognized value for --enable-nls; disabling Native Language Support])
md_nls=no
fi
SUBDIR_PO=
if test "x$md_nls" = xyes; then
AC_CHECK_HEADERS([libintl.h],
[AC_CHECK_DECLS([gettext, ngettext, bindtextdomain, textdomain], [], [md_nls=no], [AC_INCLUDES_DEFAULT
@%:@include <libintl.h>])], [md_nls=no], [AC_INCLUDES_DEFAULT])
if test "x$md_nls" = xyes; then
AC_CHECK_HEADERS([locale.h],
[AC_CHECK_DECLS([setlocale, LC_MESSAGES], [], [md_nls=no], [AC_INCLUDES_DEFAULT
@%:@include <locale.h>])], [md_nls=no], [AC_INCLUDES_DEFAULT])
if test "x$md_nls" = xyes; then
AC_SEARCH_LIBS([ngettext], [intl], [], [md_nls=no])
fi
fi
if test "x$md_nls" = xyes; then
AC_DEFINE([HAVE_NLS], [1], [Define to 1 to enable Native Language Support.])
SUBDIR_PO=po
else
AC_MSG_WARN([disabling Native Language Support])
fi
fi[]dnl
AC_SUBST([SUBDIR_PO])dnl
])# MD_NLS