-
Notifications
You must be signed in to change notification settings - Fork 0
/
cover-control-arduino.ino
186 lines (153 loc) · 4.69 KB
/
cover-control-arduino.ino
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
/*
Copyright 2021 Oliver Heimlich <[email protected]>
Licensed under the Apache License, Version 2.0 (the "License");
you may not use this file except in compliance with the License.
You may obtain a copy of the License at
http://www.apache.org/licenses/LICENSE-2.0
Unless required by applicable law or agreed to in writing, software
distributed under the License is distributed on an "AS IS" BASIS,
WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
See the License for the specific language governing permissions and
limitations under the License.
*/
/*
Moves the sunscreen or window in the desired position.
Listen on UDP port 8888 for commands 'window open', 'window close', 'curtain open', and 'curtain close'.
The user may override the curtain position via PINs A2 and A3 (e. g. install a
wall switch).
The remote control for the window is connected to PINs 2/3.
The remote controls for the curtains is connected to PINs 5/6 and 8/9.
*/
#include <Ethernet.h>
#include <EthernetUdp.h>
const byte MAC[] = { 0x12, 0x06, 0x69, 0x7d, 0xf7, 0x10 };
const unsigned int LISTEN_PORT = 8888;
const int OPTO_DOWN[] = {2, 5, 8};
const int OPTO_UP[] = {3, 6, 9};
const int MANUAL_DOWN = A3;
const int MANUAL_UP = A2;
enum OperationMode { automatic, manual_down, manual_up };
enum Position { unknown, up, down };
Position automaticPosition[] = {unknown, unknown, unknown};
Position currentPosition[] = {unknown, unknown, unknown};
OperationMode curtainOpMode = automatic;
char packetBuffer[UDP_TX_PACKET_MAX_SIZE];
EthernetUDP udp;
void setup() {
for (int idx = 0; idx < (sizeof(OPTO_DOWN) / sizeof(int)); idx++) {
pinMode(OPTO_DOWN[idx], OUTPUT);
pinMode(OPTO_UP[idx], OUTPUT);
}
Ethernet.begin(MAC);
udp.begin(LISTEN_PORT);
}
void loop() {
Ethernet.maintain();
updateAutomaticPosition();
curtainOpMode = getOpModeStable();
for (int idx = 0; idx < (sizeof(OPTO_DOWN) / sizeof(int)); idx++) {
setPosition(idx, getTargetPosition(idx));
}
}
// Receive commands as UDP packets and set the automaticPosition[] accordingly
void updateAutomaticPosition() {
while (true) {
int packetSize = udp.parsePacket();
if (packetSize == 0) {
return;
}
udp.read(packetBuffer, UDP_TX_PACKET_MAX_SIZE);
if (packetSize < UDP_TX_PACKET_MAX_SIZE) {
packetBuffer[packetSize] = 0x00;
}
if (strcmp(packetBuffer, "window open") == 0) {
automaticPosition[0] = up;
} else if (strcmp(packetBuffer, "window close") == 0) {
automaticPosition[0] = down;
} else if (strcmp(packetBuffer, "curtain open") == 0) {
automaticPosition[1] = up;
automaticPosition[2] = up;
} else if (strcmp(packetBuffer, "curtain close") == 0) {
automaticPosition[1] = down;
automaticPosition[2] = down;
} else {
// unsupported command
}
}
}
// Determine the target position for a remote control,
// based on the wall switch and the last received command.
Position getTargetPosition(int idx) {
OperationMode opMode;
if (idx == 0) {
// The first remote control moves the window position,
// which can not be overridden by the wall switch.
opMode = automatic;
} else {
opMode = curtainOpMode;
}
switch (opMode) {
case manual_down:
return down;
case manual_up:
return up;
case automatic:
return automaticPosition[idx];
default:
return unknown;
}
}
// Read input pins until two subsequent measurements are equal.
OperationMode getOpModeStable() {
OperationMode opMode = getOpMode();
OperationMode previousOpMode;
do {
delay(200);
previousOpMode = opMode;
opMode = getOpMode();
} while (previousOpMode != opMode);
return opMode;
}
// Read input pins until none or only one pin is in HIGH state.
OperationMode getOpMode() {
while (true) {
switch (((digitalRead(MANUAL_UP) == HIGH) << 1) | (digitalRead(MANUAL_DOWN) == HIGH)) {
case 0:
return automatic;
case 1:
return manual_down;
case 2:
return manual_up;
case 3:
// Illegal state: Both up and down buttons are pressed
;
}
delay(200);
}
}
// Activate the remote control to move the window / curtain into a new position.
void setPosition(int idx, Position target) {
if (target == currentPosition[idx]) {
// nothing to do
return;
}
int opto;
switch (target) {
case up:
opto = OPTO_UP[idx];
break;
case down:
opto = OPTO_DOWN[idx];
break;
default:
// target == unknown
return;
}
// Send signal to move curtain
digitalWrite(opto, HIGH);
delay(200);
digitalWrite(opto, LOW);
// Wait until signal has been sent to avoid interference
// delay(500);
currentPosition[idx] = target;
}