emacsPackages.lspce: 1.0.0-unstable-2024-02-03 -> 1.1.0-unstable-2024…

…-07-13

pkgs/applications/editors/emacs/elisp-packages/manual-packages/lspce/default.nix

@@ -1,65 +1,29 @@
-{ lib
-, emacs
-, f
-, fetchFromGitHub
-, markdown-mode
-, rustPlatform
-, trivialBuild
-, yasnippet
+{
+  lib,
+  callPackage,
+  f,
+  lspce,
+  markdown-mode,
+  melpaBuild,
+  yasnippet,
 }:
 
 let
-  version = "1.0.0-unstable-2024-02-03";
-
-  src = fetchFromGitHub {
-    owner = "zbelial";
-    repo = "lspce";
-    rev = "543dcf0ea9e3ff5c142c4365d90b6ae8dc27bd15";
-    hash = "sha256-LZWRQOKkTjNo8jecBRholW9SHpiK0SWcV8yObojpvxo=";
-  };
-
-  meta = {
-    homepage = "https://github.com/zbelial/lspce";
-    description = "LSP Client for Emacs implemented as a module using rust";
-    license = lib.licenses.gpl3Only;
-    maintainers = [ ];
-    inherit (emacs.meta) platforms;
-  };
-
-  lspce-module = rustPlatform.buildRustPackage {
-    inherit version src meta;
-    pname = "lspce-module";
-
-    cargoHash = "sha256-W9rsi7o4KvyRoG/pqRKOBbJtUoSW549Sh8+OV9sLcxs=";
-
-    checkFlags = [
-      # flaky test
-      "--skip=msg::tests::serialize_request_with_null_params"
+  lspce-module = callPackage ./module.nix { };
+  self = melpaBuild {
+    pname = "lspce";
+    inherit (lspce-module) version src meta;
+
+    packageRequires = [
+      f
+      lspce-module
+      markdown-mode
+      yasnippet
     ];
 
-    postInstall = ''
-      mkdir -p $out/share/emacs/site-lisp
-      for f in $out/lib/*; do
-        mv $f $out/share/emacs/site-lisp/lspce-module.''${f##*.}
-      done
-      rmdir $out/lib
-    '';
+    passthru = {
+      inherit lspce-module;
+    };
   };
 in
-trivialBuild rec {
-  inherit version src meta;
-  pname = "lspce";
-
-  buildInputs = propagatedUserEnvPkgs;
-
-  propagatedUserEnvPkgs = [
-    f
-    markdown-mode
-    yasnippet
-    lspce-module
-  ];
-
-  passthru = {
-    inherit lspce-module;
-  };
-}
+self

pkgs/applications/editors/emacs/elisp-packages/manual-packages/lspce/module.nix

@@ -0,0 +1,47 @@
+{
+  lib,
+  callPackage,
+  emacsPackages,
+  fetchFromGitHub,
+  rustPlatform,
+}:
+
+let
+  self = rustPlatform.buildRustPackage {
+    pname = "lspce-module";
+    version = "1.1.0-unstable-2024-07-13";
+
+    src = fetchFromGitHub {
+      owner = "zbelial";
+      repo = "lspce";
+      rev = "01b77a4f544a912409857083842db51a20bfdbf3";
+      hash = "sha256-oew5EujNYGjk/agBw3ECAVe7GZl8rw/4M5t32JM+1T8=";
+    };
+
+    cargoHash = "sha256-YLcSaFHsm/Iw7Q3y/YkfdbYKUPW0DRmaZnZ1A9vKR14=";
+
+    checkFlags = [
+      # flaky test
+      "--skip=msg::tests::serialize_request_with_null_params"
+    ];
+
+    strictDeps = true;
+
+    # Move all lib/ files to share/emacs/site-lisp
+    postInstall = ''
+      mkdir -p $out/share/emacs/site-lisp
+      for f in $out/lib/*; do
+        mv $f $out/share/emacs/site-lisp/lspce-module.''${f##*.}
+      done
+      rmdir $out/lib
+    '';
+
+    meta = {
+      homepage = "https://github.com/zbelial/lspce";
+      description = "LSP Client for Emacs implemented as a module using rust";
+      license = lib.licenses.gpl3Only;
+      maintainers = with lib.maintainers; [ AndersonTorres ];
+    };
+  };
+in
+self