refactor(flake): create derivation manually

flake.nix

@@ -2,39 +2,26 @@
   inputs = {
     nixpkgs.url = "github:NixOS/nixpkgs";
     flake-utils.url = "github:numtide/flake-utils";
-    pnpm2nix = {
-      url = "github:nzbr/pnpm2nix-nzbr";
-      inputs = {
-        nixpkgs.follows = "nixpkgs";
-        flake-utils.follows = "flake-utils";
-      };
-    };
   };
 
   outputs = {
     flake-utils,
     nixpkgs,
-    pnpm2nix,
     ...
   }:
     flake-utils.lib.eachDefaultSystem (
       system: let
-        pkgs = import nixpkgs {
-          overlays = [pnpm2nix.outputs.overlays.default];
-          inherit system;
-        };
+        pkgs = nixpkgs.legacyPackages.${system};
       in {
         devShells.default = with pkgs;
           mkShell {
             buildInputs = [
               nodejs
-              nodejs.pkgs.pnpm
+              pnpm
             ];
           };
 
-        packages.default = pkgs.mkPnpmPackage {
-          src = ./.;
-        };
+        packages.default = pkgs.callPackage ./package.nix {};
       }
     );
 }

package.nix

@@ -0,0 +1,38 @@
+{
+  lib,
+  stdenv,
+  nodejs,
+  pnpm,
+}: let
+  packageJSON = builtins.fromJSON (builtins.readFile ./package.json);
+in
+  stdenv.mkDerivation (finalAttrs: {
+    pname = packageJSON.name;
+    version = packageJSON.version;
+
+    src = lib.cleanSource ./.;
+
+    pnpmDeps = pnpm.fetchDeps {
+      inherit (finalAttrs) pname version src;
+      hash = "sha256-yWX539W0b1R4YpIcDEVjCl3GzxI8kkpgT8GkCBrrY60=";
+    };
+
+    nativeBuildInputs = [nodejs pnpm.configHook];
+
+    buildPhase = ''
+      runHook preBuild
+
+      pnpm build
+
+      runHook postBuild
+    '';
+
+    installPhase = ''
+      runHook preInstall
+
+      mkdir -p $out
+      cp -r {dist/main.js,manifest.json} $out/
+
+      runHook postInstall
+    '';
+  })