sgdboop: init at 1.2.8

pkgs/by-name/ca/canvasdraw/package.nix

@@ -0,0 +1,63 @@
+{
+  lib,
+  stdenv,
+  fetchurl,
+
+  lsb-release,
+  which,
+  pkg-config,
+  gtk3,
+  fontconfig,
+  ftgl,
+  libGLU,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "canvasdraw";
+  version = "5.14";
+
+  src = fetchurl {
+    url = "mirror://sourceforge/canvasdraw/${version}/Docs%20and%20Sources/cd-${version}_Sources.tar.gz";
+    hash = "sha256-xE7cBBExyaakKTPIeaZE1r2CjWCyikuFWpzeYV/Fr08=";
+  };
+
+  nativeBuildInputs = [
+    lsb-release
+    which
+    pkg-config
+  ];
+
+  buildInputs = [
+    gtk3
+    fontconfig
+    ftgl
+    libGLU
+  ];
+
+  sourceRoot = "cd/src";
+
+  makeFlags = [
+    "USE_PKGCONFIG=Yes"
+    "USE_GTK3=Yes"
+    "cd"
+    "cdgl"
+    "cdcontextplus"
+  ];
+
+  installPhase = ''
+    runHook preInstall
+    install -m755 -d "$out/lib"
+    install -m644 ../lib/*/lib*.so "$out/lib"
+    install -m755 -d "$out/include"
+    install -m644 ../include/* "$out/include"
+    runHook postInstall
+  '';
+
+  meta = {
+    description = "C platform-independent graphics library, aka canvasdraw";
+    homepage = "http://www.tecgraf.puc-rio.br/cd/";
+    license = lib.licenses.mit;
+    maintainers = with lib.maintainers; [ saturn745 ];
+    platforms = lib.platforms.linux;
+  };
+}

pkgs/by-name/im/imtoolkit/package.nix

@@ -0,0 +1,59 @@
+{
+  lib,
+  stdenv,
+  fetchurl,
+
+  lsb-release,
+  which,
+  pkg-config,
+  gtk3,
+  fontconfig,
+  ftgl,
+  libGLU,
+  fftw,
+  fftwFloat,
+  lua,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "imtoolkit";
+  version = "3.15";
+
+  src = fetchurl {
+    url = "mirror://sourceforge/imtoolkit/${version}/Docs%20and%20Sources/im-${version}_Sources.tar.gz";
+    hash = "sha256-NsxCV/j1+BEouFS7O+KcXL3QkUdlKPMVr2ZtCTC5tX4=";
+  };
+
+  nativeBuildInputs = [
+    lsb-release
+    which
+    pkg-config
+  ];
+
+  buildInputs = [
+    gtk3
+    fontconfig
+    ftgl
+    libGLU
+    fftw
+    fftwFloat
+    lua
+  ];
+
+  sourceRoot = "im/src";
+
+  installPhase = ''
+    install -m755 -d "$out/lib"
+    install -m644 ../lib/*/lib*.so "$out/lib"
+    install -m755 -d "$out/include"
+    install -m644 ../include/* "$out/include"
+  '';
+
+  meta = {
+    description = "Toolkit for Digital Imaging";
+    homepage = "http://www.tecgraf.puc-rio.br/im/";
+    license = lib.licenses.mit;
+    maintainers = with lib.maintainers; [ saturn745 ];
+    platforms = lib.platforms.linux;
+  };
+}

pkgs/by-name/iu/iup/package.nix

@@ -0,0 +1,77 @@
+{
+  lib,
+  stdenv,
+  fetchurl,
+
+  lsb-release,
+  which,
+  pkg-config,
+  gtk3,
+  canvasdraw,
+  libGLU,
+  ftgl,
+  imtoolkit,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "iup";
+  version = "3.31";
+
+  src = fetchurl {
+    url = "mirror://sourceforge/iup/${version}/Docs%20and%20Sources/${pname}-${version}_Sources.tar.gz";
+    hash = "sha256-rYL2KweC5G/31KsWdl3yHLF+Z6xrjnLFDMhVH/VKFHQ=";
+  };
+
+  nativeBuildInputs = [
+    lsb-release
+    which
+    pkg-config
+  ];
+
+  buildInputs = [
+    gtk3
+    canvasdraw
+    libGLU
+    ftgl
+    imtoolkit
+  ];
+
+  makeFlags = [
+    "USE_PKGCONFIG=Yes"
+    "USE_GTK3=Yes"
+    "USE_STATIC="
+    "LINK_CAIRO=Yes"
+
+    "iup"
+    "iupgtk"
+    "iupcd"
+    "iupcontrols"
+    "iupgl"
+    "iup_plot"
+    "iup_mglplot"
+    "iupglcontrols"
+    "iupim"
+    "iupole"
+    "iup_scintilla"
+    "iupim"
+    "iuptuio"
+    "iupimglib"
+    "ledc"
+    "iupview"
+  ];
+
+  installPhase = ''
+    install -m755 -d "$out/lib"
+    install -m644 lib/*/lib*.so "$out/lib"
+    install -m755 -d "$out/include"
+    install -m644 include/* "$out/include"
+  '';
+
+  meta = {
+    description = "C cross platform GUI toolkit";
+    homepage = "https://www.tecgraf.puc-rio.br/iup/";
+    license = lib.licenses.mit;
+    maintainers = with lib.maintainers; [ saturn745 ];
+    platforms = lib.platforms.linux;
+  };
+}

pkgs/by-name/sg/sgdboop/package.nix

@@ -0,0 +1,52 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  curl,
+  iup,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "sgdboop";
+  version = "1.2.8";
+
+  src = fetchFromGitHub {
+    owner = "SteamGridDB";
+    repo = "SGDBoop";
+    rev = "v${version}";
+    hash = "sha256-bdSzTwObMEBe1pHTDwXeJ3GXmOwwFp4my7qTmifX218=";
+  };
+
+  makeFlags = [
+    # Makefile copies a bundled libiup.so, so put it somewhere it won't be found
+    "USER_LIB_PATH=ignored"
+
+    # The Flakepak install just copies things to /app - otherwise wants to do things with XDG
+    "FLATPAK_ID=fake"
+  ];
+
+  postPatch = ''
+    substituteInPlace "linux-release/com.steamgriddb.SGDBoop.desktop" \
+      --replace "Exec=" "Exec=$out/bin/"
+    substituteInPlace Makefile \
+      --replace "/app/" "$out/"
+  '';
+
+  postInstall = ''
+    rm -r "$out/share/metainfo"
+  '';
+
+  buildInputs = [
+    curl
+    iup
+  ];
+
+  meta = {
+    description = "A program used for applying custom artwork to Steam, using SteamGridDB";
+    homepage = "https://github.com/SteamGridDB/SGDBoop/";
+    license = lib.licenses.zlib;
+    maintainers = with lib.maintainers; [ saturn745 ];
+    mainProgram = "SGDBoop";
+    platforms = lib.platforms.linux;
+  };
+}